Tcl Library Source Code

Artifact 5ca869c7867fe223e366fc8be3f6d0af0c856c7e:

• File modules/term/receive.tcl — part of check-in [9fe1857a19] at 2006-07-24 03:31:55 on branch trunk — * receive.tcl: New file, package. Basic receiver functionality * receive.man: (getting chars, event listener). Documentation. * bind.tcl: New file, package. Recognition of character * term_bind.man: sequences in the input, execution of actions. Dispatcher. A 'bind' for character sequences. * pkgIndex.tcl: New packages registered. * ../../examples/term/menu2: Example for receive and bind. * ansi_code.man: Typos. * ansi_send.man: * term.man: * term_send.man: (user: andreas_kupries size: 1317)

# -*- tcl -*-
# ### ### ### ######### ######### #########
## Terminal packages - Generic receiver operations

# ### ### ### ######### ######### #########
## Requirements

namespace eval ::term::receive {}

# ### ### ### ######### ######### #########
## API. Read character from specific channel,
##      or default (stdin). Processing of
##      character sequences.

proc ::term::receive::getch {{chan stdin}} {
    return [read $chan 1]
}

proc ::term::receive::listen {cmd {chan stdin}} {
    fconfigure $chan -blocking 0
    fileevent  $chan readable \
	    [list ::term::receive::Foreach $chan $cmd]
    return
}

proc ::term::receive::unlisten {{chan stdin}} {
    fileevent $chan readable {}
    return
}

# ### ### ### ######### ######### #########
## Internals

proc ::term::receive::Foreach {chan cmd} {
    set string [read $chan]
    if {[string length $string]} {
	#puts stderr "F($string)"
	uplevel #0 [linsert $cmd end process $string]
    }
    if {[eof $chan]} {
	close $chan
	uplevel #0 [linsert $cmd end eof]
    }
    return
}

# ### ### ### ######### ######### #########
## Initialization

namespace eval ::term::receive {
    namespace export getch listen
}

# ### ### ### ######### ######### #########
## Ready

package provide term::receive 0.1

##
# ### ### ### ######### ######### #########